1

!define APPNAME "OpenTTD"   ; Define application name

     2

!define APPVERSION "0.5.3"  ; Define application version

     4

     5

!define APPURLLINK "http://www.openttd.org"

     6

!define APPNAMEANDVERSION "${APPNAME} ${APPVERSION}"

     7

!define APPVERSIONINTERNAL "${APPVERSION}.0" ; Needs to be of the format X.X.X.X

     8

     9

!define MUI_ICON "..\..\..\openttd.ico"

    10

!define MUI_UNICON "..\..\..\openttd.ico"

    11

!define MUI_WELCOMEFINISHPAGE_BITMAP "welcome.bmp"

    12

!define MUI_HEADERIMAGE

    13

!define MUI_HEADERIMAGE_BITMAP "top.bmp"

    14

    15

BrandingText "OpenTTD Installer"

    16

SetCompressor LZMA

    17

    18

; Version Info

    19

Var AddWinPrePopulate

    20

VIProductVersion "${APPVERSIONINTERNAL}"

    21

VIAddVersionKey "ProductName" "OpenTTD Installer"

    22

VIAddVersionKey "Comments" "Installs ${APPNAMEANDVERSION}"

    23

VIAddVersionKey "CompanyName" "OpenTTD Developers"

    24

VIAddVersionKey "FileDescription" "Installs ${APPNAMEANDVERSION}"

    25

VIAddVersionKey "ProductVersion" "${APPVERSION}"

    26

VIAddVersionKey "InternalName" "InstOpenTTD"

    27

VIAddVersionKey "FileVersion" "${APPVERSION}"

    28

VIAddVersionKey "LegalCopyright" " "

    29

; Main Install settings

    30

Name "${APPNAMEANDVERSION}"

    31

    32

; NOTE: Keep trailing backslash!

    33

InstallDir "$PROGRAMFILES\OpenTTD\"

    34

InstallDirRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Install Folder"

    35

OutFile "openttd-${APPVERSION}-win32.exe"

    36

CRCCheck force

    37

    38

ShowInstDetails show

    39

ShowUninstDetails show

    40

    41

Var SHORTCUTS

    42

Var CDDRIVE

    43

    44

; Modern interface settings

    45

!include "MUI.nsh"

    46

    47

!define MUI_ABORTWARNING

    48

    49

!insertmacro MUI_PAGE_WELCOME

    50

    51

!define MUI_LICENSEPAGE_RADIOBUTTONS

    52

!insertmacro MUI_DEFAULT MUI_LICENSEPAGE_RADIOBUTTONS_TEXT_ACCEPT "I &accept this agreement"

    53

!insertmacro MUI_DEFAULT MUI_LICENSEPAGE_RADIOBUTTONS_TEXT_DECLINE "I &do not accept this agreement"

    54

!insertmacro MUI_PAGE_LICENSE "..\..\..\COPYING"

    55

    56

!insertmacro MUI_PAGE_COMPONENTS

    57

    58

;---------------------------------

    59

; Custom page for finding TTDLX CD

    60

Page custom SelectCDEnter SelectCDExit ": TTD folder"

    61

    62

!insertmacro MUI_PAGE_DIRECTORY

    63

    64

;Start Menu Folder Page Configuration

    65

!define MUI_STARTMENUPAGE_DEFAULTFOLDER $SHORTCUTS

    66

!define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKEY_LOCAL_MACHINE"

    67

!define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD"

    68

!define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Shortcut Folder"

    69

    70

!insertmacro MUI_PAGE_STARTMENU "OpenTTD" $SHORTCUTS

    71

    72

!insertmacro MUI_PAGE_INSTFILES

    73

    74

;-----------------------------------------------------

    75

; New custom page to show UNICODE and MSLU information

    76

Page custom ShowWarningsPage

    77

    78

!define MUI_FINISHPAGE_RUN "$INSTDIR\openttd.exe"

    79

!define MUI_FINISHPAGE_LINK "Visit the OpenTTD site for latest news, FAQs and downloads"

    80

!define MUI_FINISHPAGE_LINK_LOCATION "${APPURLLINK}"

    81

!define MUI_FINISHPAGE_NOREBOOTSUPPORT

    82

!define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\readme.txt"

    83

!define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED

    84

!define MUI_WELCOMEFINISHPAGE_CUSTOMFUNCTION_INIT DisableBack

    85

    86

!insertmacro MUI_PAGE_FINISH

    87

!insertmacro MUI_UNPAGE_CONFIRM

    88

!insertmacro MUI_UNPAGE_INSTFILES

    89

    90

; Set languages (first is default language)

    91

!insertmacro MUI_LANGUAGE "English"

    92

!insertmacro MUI_RESERVEFILE_LANGDLL

    93

    94

;--------------------------------------------------------------

    95

; (Core) OpenTTD install section. Copies all internal game data

    96

Section "!OpenTTD" Section1

    97

	; Overwrite files by default, but don't complain on failure

    98

	SetOverwrite try

    99

   100

	; Make savegame folder

   101

	SetOutPath "$INSTDIR\save"

   102

	; Define root variable relative to installer

   103

	!define PATH_ROOT "..\..\..\"

   104

   105

	; Copy language files

   106

	SetOutPath "$INSTDIR\lang\"

   107

	File ${PATH_ROOT}lang\*.lng

   108

	File ${PATH_ROOT}lang\english.txt

   109

   110

	; Copy data files

   111

	SetOutPath "$INSTDIR\data\"

   112

	File ${PATH_ROOT}data\*.grf

   113

	File ${PATH_ROOT}data\opntitle.dat

   114

	; Copy scenario files (don't choke if they don't exist)

   115

	SetOutPath "$INSTDIR\scenario\"

   116

	File /nonfatal ${PATH_ROOT}scenario\*.scn

   117

   118

	; Copy heightmap files (don't choke if they don't exist)

   119

	SetOutPath "$INSTDIR\scenario\heightmap\"

   120

	File /nonfatal ${PATH_ROOT}scenario\heightmap\*.*

   121

   122

	; Copy the rest of the stuff

   123

	SetOutPath "$INSTDIR\"

   124

   125

	; Copy text files

   126

	File ${PATH_ROOT}changelog.txt

   127

	File ${PATH_ROOT}COPYING

   128

	File ${PATH_ROOT}readme.txt

   129

	File ${PATH_ROOT}known-bugs.txt

   130

   131

	; Copy executable

   132

	File /oname=openttd.exe ${PATH_ROOT}Release\openttd.exe

   133

	File ${PATH_ROOT}strgen\Debug\strgen.exe

   134

   135

   136

	; Delete old files from the main dir. they are now placed in data/ and lang/

   137

	Delete "$INSTDIR\*.lng"

   138

	Delete "$INSTDIR\*.grf"

   139

	Delete "$INSTDIR\sample.cat"

   140

	Delete "$INSTDIR\ttd.exe"

   141

   142

   143

	; Create the Registry Entries

   144

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Comments" "Visit ${APPURLLINK}"

   145

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "DisplayIcon" "$INSTDIR\openttd.exe,0"

   146

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "DisplayName" "OpenTTD ${APPVERSION}"

   147

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "DisplayVersion" "${APPVERSION}"

   148

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "HelpLink" "${APPURLLINK}"

   149

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Install Folder" "$INSTDIR"

   150

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Publisher" "OpenTTD"

   151

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Shortcut Folder" "$SHORTCUTS"

   152

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "UninstallString" "$INSTDIR\uninstall.exe"

   153

	WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "URLInfoAbout" "${APPURLLINK}"

   154

	; This key sets the Version DWORD that new installers will check against

   155

	WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Version" ${INSTALLERVERSION}

   156

   157

	!insertmacro MUI_STARTMENU_WRITE_BEGIN "OpenTTD"

   158

	CreateShortCut "$DESKTOP\OpenTTD.lnk" "$INSTDIR\openttd.exe"

   159

	CreateDirectory "$SMPROGRAMS\$SHORTCUTS"

   160

	CreateShortCut "$SMPROGRAMS\$SHORTCUTS\OpenTTD.lnk" "$INSTDIR\openttd.exe"

   161

	CreateShortCut "$SMPROGRAMS\$SHORTCUTS\Uninstall.lnk" "$INSTDIR\uninstall.exe"

   162

	CreateShortCut "$SMPROGRAMS\$SHORTCUTS\Readme.lnk" "$INSTDIR\Readme.txt"

   163

	CreateShortCut "$SMPROGRAMS\$SHORTCUTS\Changelog.lnk" "$INSTDIR\Changelog.txt"

   164

	CreateShortCut "$SMPROGRAMS\$SHORTCUTS\Known-bugs.lnk" "$INSTDIR\known-bugs.txt"

   165

	!insertmacro MUI_STARTMENU_WRITE_END

   166

SectionEnd

   167

   168

;----------------------------------------------------------------------------------

   169

; TTDLX files install section. Copies all needed TTDLX files from CD or install dir

   170

Section "Copy Game Graphics" Section2

   171

	; Let's copy the files with size approximation

   172

	SetOutPath "$INSTDIR\gm"

   173

	CopyFiles "$CDDRIVE\gm\*.gm" "$INSTDIR\gm\" 1028

   174

	SetOutPath "$INSTDIR\data\"

   175

	CopyFiles "$CDDRIVE\sample.cat" "$INSTDIR\data\sample.cat" 1566

   176

	; Copy Windows files

   177

	CopyFiles "$CDDRIVE\trg1r.grf" "$INSTDIR\data\trg1r.grf" 2365

   178

	CopyFiles "$CDDRIVE\trgcr.grf" "$INSTDIR\data\trgcr.grf" 260

   179

	CopyFiles "$CDDRIVE\trghr.grf" "$INSTDIR\data\trghr.grf" 400

   180

	CopyFiles "$CDDRIVE\trgir.grf" "$INSTDIR\data\trgir.grf" 334

   181

	CopyFiles "$CDDRIVE\trgtr.grf" "$INSTDIR\data\trgtr.grf" 546

   182

	; Copy DOS files

   183

	CopyFiles "$CDDRIVE\trg1.grf" "$INSTDIR\data\trg1.grf" 2365

   184

	CopyFiles "$CDDRIVE\trgc.grf" "$INSTDIR\data\trgc.grf" 260

   185

	CopyFiles "$CDDRIVE\trgh.grf" "$INSTDIR\data\trgh.grf" 400

   186

	CopyFiles "$CDDRIVE\trgi.grf" "$INSTDIR\data\trgi.grf" 334

   187

	CopyFiles "$CDDRIVE\trgt.grf" "$INSTDIR\data\trgt.grf" 546

   188

	SetOutPath "$INSTDIR\"

   189

SectionEnd

   190

   191

;-------------------------------------------

   192

; Install the uninstaller (option is hidden)

   193

Section -FinishSection

   194

	WriteUninstaller "$INSTDIR\uninstall.exe"

   195

SectionEnd

   196

   197

; Modern install component descriptions

   198

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN

   199

	!insertmacro MUI_DESCRIPTION_TEXT ${Section1} "OpenTTD is a fully functional clone of TTD and is very playable."

   200

	!insertmacro MUI_DESCRIPTION_TEXT ${Section2} "Copies the game graphics. Requires TTD (for Windows)."

   201

!insertmacro MUI_FUNCTION_DESCRIPTION_END

   202

   203

;-----------------------------------------------

   204

; Uninstall section, deletes all installed files

   205

Section "Uninstall"

   206

	MessageBox MB_YESNO|MB_ICONQUESTION \

   207

		"Remove the save game folders located at $\"$INSTDIR\save?$\"$\n \

   208

		If you choose Yes, your saved games will be deleted." \

   209

		IDYES RemoveSavedGames IDNO NoRemoveSavedGames

   210

	RemoveSavedGames:

   211

		Delete "$INSTDIR\save\autosave\*"

   212

		RMDir "$INSTDIR\save\autosave"

   213

		Delete "$INSTDIR\save\*"

   214

		RMDir "$INSTDIR\save"

   215

	NoRemoveSavedGames:

   216

   217

	MessageBox MB_YESNO|MB_ICONQUESTION \

   218

		"Remove the scenario folders located at $\"$INSTDIR\scenario?$\"$\n \

   219

		If you choose Yes, your scenarios will be deleted." \

   220

		IDYES RemoveScen IDNO NoRemoveScen

   221

	RemoveScen:

   222

		Delete "$INSTDIR\scenario\heightmap*"

   223

		RMDir "$INSTDIR\scenario\heightmap"

   224

		Delete "$INSTDIR\scenario\*"

   225

		RMDir "$INSTDIR\scenario"

   226

	NoRemoveScen:

   227

   228

	; Remove from registry...

   229

	!insertmacro MUI_STARTMENU_GETFOLDER "OpenTTD" $SHORTCUTS

   230

	ReadRegStr $SHORTCUTS HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Shortcut Folder"

   231

   232

	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD"

   233

   234

	; Delete self

   235

	Delete "$INSTDIR\uninstall.exe"

   236

   237

	; Delete Shortcuts

   238

	Delete "$DESKTOP\OpenTTD.lnk"

   239

	Delete "$SMPROGRAMS\$SHORTCUTS\OpenTTD.lnk"

   240

	Delete "$SMPROGRAMS\$SHORTCUTS\Uninstall.lnk"

   241

	Delete "$SMPROGRAMS\$SHORTCUTS\Readme.lnk"

   242

	Delete "$SMPROGRAMS\$SHORTCUTS\Changelog.lnk"

   243

	Delete "$SMPROGRAMS\$SHORTCUTS\Known-bugs.lnk"

   244

   245

	; Clean up OpenTTD dir

   246

	Delete "$INSTDIR\changelog.txt"

   247

	Delete "$INSTDIR\readme.txt"

   248

	Delete "$INSTDIR\known-bugs.txt"

   249

	Delete "$INSTDIR\openttd.exe"

   250

	Delete "$INSTDIR\strgen.exe"

   251

	Delete "$INSTDIR\COPYING"

   252

	Delete "$INSTDIR\INSTALL.LOG"

   253

	Delete "$INSTDIR\crash.log"

   254

	Delete "$INSTDIR\openttd.cfg"

   255

	Delete "$INSTDIR\hs.dat"

   256

	Delete "$INSTDIR\cached_sprites.*"

   257

	Delete "$INSTDIR\save\autosave\network*.tmp" ; temporary network file

   258

   259

	; Data files

   260

	Delete "$INSTDIR\data\opntitle.dat"

   261

   262

	Delete "$INSTDIR\data\2ccmap.grf"

   263

	Delete "$INSTDIR\data\airports.grf"

   264

	Delete "$INSTDIR\data\autorail.grf"

   265

	Delete "$INSTDIR\data\canalsw.grf"

   266

	Delete "$INSTDIR\data\dosdummy.grf"

   267

	Delete "$INSTDIR\data\elrailsw.grf"

   268

	Delete "$INSTDIR\data\nsignalsw.grf"

   269

	Delete "$INSTDIR\data\openttd.grf"

   270

	Delete "$INSTDIR\data\trkfoundw.grf"

   271

   272

	Delete "$INSTDIR\data\sample.cat"

   273

	; Windows Data files

   274

	Delete "$INSTDIR\data\trg1r.grf"

   275

	Delete "$INSTDIR\data\trghr.grf"

   276

	Delete "$INSTDIR\data\trgtr.grf"

   277

	Delete "$INSTDIR\data\trgcr.grf"

   278

	Delete "$INSTDIR\data\trgir.grf"

   279

	; Dos Data files

   280

	Delete "$INSTDIR\data\trg1.grf"

   281

	Delete "$INSTDIR\data\trgh.grf"

   282

	Delete "$INSTDIR\data\trgt.grf"

   283

	Delete "$INSTDIR\data\trgc.grf"

   284

	Delete "$INSTDIR\data\trgi.grf"

   285

   286

	; Music

   287

	Delete "$INSTDIR\gm\*.gm"

   288

   289

	; Language files

   290

	Delete "$INSTDIR\lang\*.lng"

   291

	Delete "$INSTDIR\lang\english.txt"

   292

   293

	; Remove remaining directories

   294

	RMDir "$SMPROGRAMS\$SHORTCUTS\Extras\"

   295

	RMDir "$SMPROGRAMS\$SHORTCUTS"

   296

	RMDir "$INSTDIR\gm"

   297

	RMDir "$INSTDIR\lang"

   298

	RMDir "$INSTDIR\data"

   299

	RMDir "$INSTDIR"

   300

   301

SectionEnd

   302

   303

;------------------------------------------------------------

   304

; Custom page function to find the TTDLX CD/install location

   305

Function SelectCDEnter

   306

	SectionGetFlags ${Section2} $0

   307

	IntOp $1 $0 & 0x80 ; bit 7 set by upgrade, no need to copy files

   308

	IntCmp $1 1 DoneCD ; Upgrade doesn't need copy files

   309

   310

	IntOp $0 $0 & 1

   311

	IntCmp $0 1 NoAbort

   312

	Abort

   313

NoAbort:

   314

   315

	GetTempFileName $R0

   316

	!insertmacro MUI_HEADER_TEXT "Locate TTD" "Setup needs the location of Transport Tycoon Deluxe in order to continue."

   317

	!insertmacro MUI_INSTALLOPTIONS_EXTRACT_AS "CDFinder.ini" "CDFinder"

   318

   319

	ClearErrors

   320

	; Now, let's populate $CDDRIVE

   321

	ReadRegStr $R0 HKLM "SOFTWARE\Fish Technology Group\Transport Tycoon Deluxe" "HDPath"

   322

	IfErrors NoTTD

   323

	StrCmp $CDDRIVE "" 0 Populated

   324

	StrCpy $CDDRIVE $R0

   325

Populated:

   326

	StrCpy $AddWinPrePopulate "Setup has detected your TTD folder. Don't change the folder. Simply press Next."

   327

	Goto TruFinish

   328

NoTTD:

   329

	StrCpy $AddWinPrePopulate "Setup couldn't find TTD. Please enter the path where the graphics files from TTD are stored and press Next to continue."

   330

TruFinish:

   331

	ClearErrors

   332

	!insertmacro MUI_INSTALLOPTIONS_WRITE "CDFinder" "Field 2" "State" $CDDRIVE          ; TTDLX path

   333

	!insertmacro MUI_INSTALLOPTIONS_WRITE "CDFinder" "Field 3" "Text" $AddWinPrePopulate ; Caption

   334

DoneCD:

   335

	; Initialize the dialog *AFTER* we've changed the text otherwise we won't see the changes

   336

	!insertmacro MUI_INSTALLOPTIONS_INITDIALOG "CDFinder"

   337

	!insertmacro MUI_INSTALLOPTIONS_SHOW

   338

FunctionEnd

   339

   340

;----------------------------------------------------------------

   341

; Custom page function when 'next' is selected for the TTDLX path

   342

Function SelectCDExit

   343

	!insertmacro MUI_INSTALLOPTIONS_READ $CDDRIVE "CDFinder" "Field 2" "State"

   344

	; If trg1r.grf does not exist at the path, retry with DOS version

   345

	IfFileExists $CDDRIVE\trg1r.grf "" DosCD

   346

	IfFileExists $CDDRIVE\trgir.grf "" NoCD

   347

	IfFileExists $CDDRIVE\sample.cat hasCD NoCD

   348

DosCD:

   349

	IfFileExists $CDDRIVE\TRG1.GRF "" NoCD

   350

	IfFileExists $CDDRIVE\TRGI.GRF "" NoCD

   351

	IfFileExists $CDDRIVE\SAMPLE.CAT hasCD NoCD

   352

NoCD:

   353

	MessageBox MB_OK "Setup cannot continue without the Transport Tycoon Deluxe Location!"

   354

	Abort

   355

hasCD:

   356

FunctionEnd

   357

   358

;----------------------------------------------------------------------------------

   359

; Disable the "Back" button on finish page if the installer is run on Win9x systems

   360

Function DisableBack

   361

	Call GetWindowsVersion

   362

	Pop $R0

   363

	StrCmp $R0 "win9x" 0 WinNT

   364

	!insertmacro MUI_INSTALLOPTIONS_WRITE "ioSpecial.ini" "Settings" "BackEnabled" "0"

   365

WinNT:

   366

	ClearErrors

   367

FunctionEnd

   368

   369

;----------------------------------------------------------------------------------

   370

; Custom page function to show notices for running OpenTTD (only for win32 systems)

   371

; We have extracted this custom page as Notice in the .onInit function

   372

Function ShowWarningsPage

   373

	Call GetWindowsVersion

   374

	Pop $R0

   375

	; Don't show the UNICODE notice if the installer is run on Win9x systems

   376

	StrCmp $R0 "win9x" 0 WinNT

   377

	Abort

   378

WinNT:

   379

	!insertmacro MUI_HEADER_TEXT "Installation Complete" "Important notices for OpenTTD usage."

   380

	!insertmacro MUI_INSTALLOPTIONS_EXTRACT_AS "notice.ini" "Notice"

   381

	!insertmacro MUI_INSTALLOPTIONS_INITDIALOG "Notice"

   382

	ClearErrors

   383

	!insertmacro MUI_INSTALLOPTIONS_SHOW

   384

FunctionEnd

   385

   386

;-------------------------------------------------------------------------------

   387

; Determine windows version, returns "win9x" if Win9x/Me or "winnt" on the stack

   388

Function GetWindowsVersion

   389

	ClearErrors

   390

	StrCpy $R0 "winnt"

   391

   392

	ReadRegStr $R1 HKLM "SOFTWARE\MICROSOFT\WINDOWS NT\CurrentVersion" CurrentVersion

   393

	IfErrors 0 WinNT

   394

	StrCpy $R0 "win9x"

   395

WinNT:

   396

	ClearErrors

   397

	Push $R0

   398

FunctionEnd

   399

   400

Var OLDVERSION

   401

Var UninstallString

   402

   403

;-----------------------------------------------------------------------------------

   404

; NSIS Initialize function, determin if we are going to install/upgrade or uninstall

   405

Function .onInit

   406

	StrCpy $SHORTCUTS "OpenTTD"

   407

   408

	SectionSetFlags 0 17

   409

   410

	; Starts Setup - let's look for an older version of OpenTTD

   411

	ReadRegDWORD $R8 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Version"

   412

   413

	IfErrors ShowWelcomeMessage ShowUpgradeMessage

   414

ShowWelcomeMessage:

   415

	ReadRegStr $R8 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "Version"

   416

	; In the event someone still has OpenTTD 0.1, this will detect that (that installer used a string instead of dword entry)

   417

	IfErrors FinishCallback

   418

   419

ShowUpgradeMessage:

   420

	IntCmp ${INSTALLERVERSION} $R8 VersionsAreEqual InstallerIsOlder  WelcomeToSetup

   421

WelcomeToSetup:

   422

	; An older version was found.  Let's let the user know there's an upgrade that will take place.

   423

	ReadRegStr $OLDVERSION HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "DisplayVersion"

   424

	; Gets the older version then displays it in a message box

   425

	MessageBox MB_OK|MB_ICONINFORMATION \

   426

		"Welcome to ${APPNAMEANDVERSION} Setup.$\n \

   427

		This will allow you to upgrade from version $OLDVERSION."

   428

	SectionSetFlags ${Section2} 0x80 ; set bit 7

   429

	Goto FinishCallback

   430

   431

VersionsAreEqual:

   432

	ReadRegStr $UninstallString HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\OpenTTD" "UninstallString"

   433

	IfFileExists "$UninstallString" "" FinishCallback

   434

	MessageBox MB_YESNO|MB_ICONQUESTION \

   435

		"Setup detected ${APPNAMEANDVERSION} on your system. That's the version this program will install.$\n \

   436

		Are you trying to uninstall it?" \

   437

		IDYES DoUninstall IDNO FinishCallback

   438

DoUninstall: ; You have the same version as this installer.  This allows you to uninstall.

   439

	Exec "$UninstallString"

   440

	Quit

   441

   442

InstallerIsOlder:

   443

	MessageBox MB_OK|MB_ICONSTOP \

   444

		"You have a newer version of ${APPNAME}.$\n \

   445

		Setup will now exit."

   446

	Quit

   447

   448

FinishCallback:

   449

	ClearErrors

   450

FunctionEnd

   451

; eof

   452